[此贴子已经被作者于2006-9-9 4:13:07编辑过]

谢谢各位大哥,问题解决了,好兴奋!

找不到修改颜色的代码,大哥们帮我看看怎么改?

'-----------------------------------------------------------------------------------------------------------------------------
  '过程名：GetPageStr
  '作  用：取得分页的通用函数
  '参  数：PageContent--分页内容,LinkUrl--链接地址,Index-首页名称
  '        FileContent--待保存的文件内容,FilePath---待保存路径,SecondDomain --二级域名 ,ShowTurnToFlag ---是否显示转到下拉框
  '------------------------------------------------------------------------------------------------------------------------------
  Sub GetPageStr(PageContent, LinkUrl, Index, FileContent, FilePath, SecondDomain, ShowTurnToFlag)
   Dim CurrPage, PageStr, TempFileContent, I, PageContentArr, J, SelectStr
   Dim TotalPage
   Dim HomeLink      '构造首页链接
   Dim LinkUrlFname  '构造其它页链接
   Dim Fname         '文件名
   Dim FExt          '扩展名
     HomeLink = LinkUrl & Index
     FExt = Mid(Trim(Index), InStrRev(Trim(Index), ".")) '分离出扩展名
     Fname = Replace(Trim(Index), FExt, "")  '分离出文件名 如 1254ddd
     LinkUrlFname = LinkUrl & Fname
    
     PageContentArr = Split(PageContent, "[NextPage]")
     TotalPage = UBound(PageContentArr)
  
     For I = LBound(PageContentArr) To TotalPage - 1
      CurrPage = I + 1
      If CurrPage = 1 And CurrPage <> TotalPage Then
    PageStr = "首页  上一页 <a href=""" & LinkUrlFname & "_" & CurrPage + 1 & FExt & """>下一页</a>  <a href= """ & LinkUrlFname & "_" & TotalPage & FExt & """>尾页</a>"
      ElseIf CurrPage = 1 And CurrPage = TotalPage Then
    PageStr = "首页  上一页 下一页 尾页"
      ElseIf CurrPage = TotalPage And CurrPage <> 2 Then  '对于最后一页刚好是第二页的要做特殊处理
     PageStr = "<a href=""" & HomeLink & """>首页</a>  <a href=""" & LinkUrlFname & "_" & CurrPage - 1 & FExt & """>上一页</a> 下一页  尾页"
      ElseIf CurrPage = TotalPage And CurrPage = 2 Then
     PageStr = "<a href=""" & HomeLink & """>首页</a>  <a href=""" & HomeLink & """>上一页</a> 下一页  尾页"
      ElseIf CurrPage = 2 Then
    PageStr = "<a href=""" & HomeLink & """>首页</a>  <a href=""" & HomeLink & """>上一页</a> <a href=""" & LinkUrlFname & "_" & CurrPage + 1 & FExt & """>下一页</a>  <a href= """ & LinkUrlFname & "_" & TotalPage & FExt & """>尾页</a>"
      Else
    PageStr = "<a href=""" & HomeLink & """>首页</a>  <a href=""" & LinkUrlFname & "_" & CurrPage - 1 & FExt & """>上一页</a> <a href=""" & LinkUrlFname & "_" & CurrPage + 1 & FExt & """>下一页</a>  <a href= """ & LinkUrlFname & "_" & TotalPage & FExt & """>尾页</a>"
      End If
     
      If CBool(ShowTurnToFlag) = True Then
      PageStr = PageStr & " 转到：<select name=""page"" size=""1"" onchange=""javascript:window.location=this.options[this.selectedIndex].value;"">"
      For J = 1 To TotalPage
       If J = CurrPage Then
      SelectStr = " selected"
       Else
      SelectStr = ""
       End If
       If J = 1 Then
      PageStr = PageStr & "<option value=""" & HomeLink & """" & SelectStr & ">第" & J & "页</option>"
       Else
      PageStr = PageStr & "<option value=""" & LinkUrlFname & "_" & J & FExt & """" & SelectStr & ">第" & J & "页</option>"
       End If
      Next
      PageStr = PageStr & "</select>"
      End If
     
      TempFileContent = Replace(FileContent, "{PageListStr}", PageContentArr(I) & PageStr & "</td></tr></table>")
     
      TempFileContent = ReplaceRA(TempFileContent, SecondDomain)
      Dim TempFilePath
      If CurrPage = 1 Then
      TempFilePath = FilePath & Index
      Else
     TempFilePath = FilePath & Fname & "_" & CurrPage & FExt
      End If
    '生成文件
     Call FSOSaveFile(Published() & TempFileContent, TempFilePath)
     Next
  End Sub